BitmapData

package
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.filters.BlurFilter;
	import flash.geom.Matrix;
	import flash.geom.Point;
	import flash.geom.Rectangle;
	import flash.utils.getDefinitionByName;
 
	import net.hires.debug.Stats;
 
	/**
	 * @author jin_u
	 * blog www.jinustudio.com/blog
	 * email jin_u@jinustudio.com
	 */
 
	public class ParticleMovement extends Sprite
	{
		private var clickBtn:Sprite;
		private var btm:Bitmap;
		private var btmData:BitmapData;
        	private var matrix:Matrix;
        	private var particles:Vector.<Particle>;
		private var maxParticle:int = 300;
		private var blur:BlurFilter;
		private var point:Point;
 
		private var stageWidth:Number = 500;
		private var stageHeight:Number = 300;
		private var ratio:Number = 0.004;
		private var friction:Number = 0.98;
 
        	public function ParticleMovement()
        	{
			stage.align 			= StageAlign.TOP_LEFT;
			stage.scaleMode 		= StageScaleMode.NO_SCALE;
 
            		this.addEventListener(Event.ADDED_TO_STAGE, this.onInit);
        	}
 
        	private function onInit(e:Event = null):void
        	{
			var ClassRef:Class = getDefinitionByName("Click") as Class;
			this.clickBtn = new ClassRef() as Sprite;
			this.clickBtn.x = Math.round(this.stageWidth / 2);
			this.clickBtn.y = Math.round(this.stageHeight / 2);
 
			this.addChild(clickBtn);
			stage.addEventListener(MouseEvent.CLICK, this.onClickBtnClick);
        	}
 
		private function onClickBtnClick(e:MouseEvent = null):void
		{
			stage.removeEventListener(MouseEvent.CLICK, this.onClickBtnClick);
			this.removeChild(this.clickBtn);
 
			this.setContent();
		}
 
		private function setContent():void
		{
			this.particles = new Vector.<Particle>;
 
			this.matrix = new Matrix();
			this.blur = new BlurFilter(2, 2, 1)
			this.point = new Point();
 
			this.createCanvas();
			this.addChild(new Stats);
 
			this.addEventListener(Event.ENTER_FRAME, this.onStageEnterFrame);
		}
 
		private function createCanvas():void
		{
			this.btmData = new BitmapData(this.stageWidth, this.stageHeight);
			this.btm = new Bitmap(this.btmData);
 
			this.addChild(this.btm);
		}
 
		private function onStageEnterFrame(e:Event = null):void
		{
			var particle:Particle = new Particle(Math.random() * 100000 + 1000000);
			particle.x = Math.random() * this.stageWidth;
			particle.y = Math.random() * this.stageHeight;
 
			this.particles.push(particle);
			if (this.particles.length > this.maxParticle - 1) this.particles.shift();
 
			this.btmData.applyFilter(this.btmData, this.btmData.rect, this.point, this.blur);
 
			var index:int = 0;
			var leng:int = this.particles.length;
			var i:int = 0;
 
			for (; i < leng; i++)
			{
				particle = this.particles[i] as Particle;
				particle.mx = (mouseX - particle.x) * ratio + particle.mx * friction;
				particle.x += particle.mx;
				particle.my = (mouseY - particle.y) * ratio + particle.my * friction;
				particle.y += particle.my;
 
				this.matrix.tx = particle.x;
				this.matrix.ty = particle.y;
				this.btmData.draw(particle, matrix);
			}
		}
	}
}
 
import flash.display.BitmapData;
 
class Particle extends BitmapData
{
	internal var x:Number = 0;
	internal var y:Number = 0;
	internal var mx:Number = 0;
	internal var my:Number = 0;
 
	public function Particle(color:uint = 0)
	{
		super(1, 1, false, color);
	}
}